Bestand:Blue Trefoil Knot.png

Uit testwiki
Naar navigatie springen Naar zoeken springen
Oorspronkelijk bestand (1.690 × 1.800 pixels, bestandsgrootte: 583 kB, MIME-type: image/png)

Dit bestand is afkomstig van Wikimedia Commons en kan ook in andere projecten gebruikt worden. De bestandsbeschrijvingspagina wordt hieronder weergegeven.

Beschrijving

Beschrijving
English: A trefoil knot.
Datum
Bron Eigen werk
Auteur Jim.belk

Licentie

Public domain Ik, de auteursrechthebbende van dit werk, geef dit werk vrij in het publieke domein. Dit is wereldwijd van toepassing.
In sommige landen is dit wettelijk niet mogelijk; in die gevallen geldt:
Ik sta iedereen toe dit werk voor eender welk doel te gebruiken, zonder enige voorwaarden, tenzij zulke voorwaarden door de wet worden voorgeschreven.

Source

This image was created using POV-Ray for Windows, version 3.6. The image was rendered to an 1800 x 1800 square, using 0.3 anti-aliasing.

#include "colors.inc"
     
/* Makes a trefoil knot using a hypotrochoid */
    
background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -25>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5
  }


light_source
  {
  <0, 20, -50>
  color White
  area_light <5, 0, 0>, <0, 5, 0>, 10, 10  /* very slow, decrease 10 to 2 for experiments */
  adaptive 3
  }
  
#declare r_tube = 0.1;
#declare num_steps = 36;
#declare step_size = 1/num_steps;
              

sphere_sweep
  {
  cubic_spline num_steps+3,
  #declare N = -1;
  #while(N <= num_steps + 1)
    #declare theta = 2 * pi * N * step_size;
    <0.3*( 2*sin(2*theta)-sin(theta) ), 0.3*( 2*cos(2*theta)+cos(theta) ), 0.3*sin(3*theta)>, r_tube
    /* uses a hypotrochoid */
    #declare N = N + 1;
  #end
  pigment { color rgb <0,0.25,1> }
  finish          
    {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 5
    }
  }


plane
  {
  <0,0,-1>, -0.4
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }

Bijschriften

Beschrijf in één regel wat dit bestand voorstelt
A trefoil knot.

Items getoond in dit bestand

beeldt af

image/png

bda6dd1a537c8f9beccd4295f70ae31ac58f521f

597.424 byte

1.800 pixel

1.690 pixel

Bestandsgeschiedenis

Klik op een datum/tijd om het bestand te zien zoals het destijds was.

Datum/tijdMiniatuurAfmetingenGebruikerOpmerking
huidige versie15 mei 2015 16:45Miniatuurafbeelding voor de versie van 15 mei 2015 16:451.690 × 1.800 (583 kB)wikimediacommons>RokerHROoptipng -o7 -i0 → 5.71% decrease

Dit bestand wordt op de volgende pagina gebruikt: